[1.12.2] Trying to add cofh as a dependency removes other libraries

[That_Martin_Guy]

I'm creating a mod that requires cofh and possibly also thermal foundation to work, but whenever I try and add both of these as a dependency all other libraries get removed, resulting in this happening, which makes modding impossible. These are all the libraries I have. When I remove the dependencies declaration forge is added as a library again.

 

build.gradle

[That_Martin_Guy]

I fixed it. Turns out cofh also needs the JEI repository to work. Not having that completely broke the project like I stated earlier...

 

Working code:

buildscript {
    repositories {
        jcenter()
        maven { url = "http://files.minecraftforge.net/maven" }
    }
    dependencies {
        classpath 'net.minecraftforge.gradle:ForgeGradle:2.3-SNAPSHOT'
    }
}
apply plugin: 'net.minecraftforge.gradle.forge'
//Only edit below this line, the above code adds and enables the necessary things for Forge to be setup.


version = "0.0.1"
group = "thatmartinguy.brightenup" // http://maven.apache.org/guides/mini/guide-naming-conventions.html
archivesBaseName = "brightenup"

sourceCompatibility = targetCompatibility = '1.8' // Need this here so eclipse task generates correctly.
compileJava {
    sourceCompatibility = targetCompatibility = '1.8'
}

minecraft {
    version = "1.12.2-14.23.4.2705"
    runDir = "run"
    
    // the mappings can be changed at any time, and must be in the following format.
    // snapshot_YYYYMMDD   snapshot are built nightly.
    // stable_#            stables are built at the discretion of the MCP team.
    // Use non-default mappings at your own risk. they may not always work.
    // simply re-run your setup task after changing the mappings to update your workspace.
    mappings = "snapshot_20171003"
    // makeObfSourceJar = false // an Srg named sources jar is made by default. uncomment this to disable.
}

repositories {
    maven {
        name = "Covers (COFH)"
        url = "http://maven.covers1624.net/"
    }
    maven {
        name = "JEI Maven"
        url = "http://dvs1.progwml6.com/files/maven"
    }
}

dependencies {
    compile 'cofh:CoFHCore:1.12.2-4.5.0.+:deobf'
    compile 'cofh:ThermalFoundation:1.12.2-2.5.+:deobf'
}

processResources {
    // this will ensure that this task is redone when the versions change.
    inputs.property "version", project.version
    inputs.property "mcversion", project.minecraft.version

    // replace stuff in mcmod.info, nothing else
    from(sourceSets.main.resources.srcDirs) {
        include 'mcmod.info'
                
        // replace version and mcversion
        expand 'version':project.version, 'mcversion':project.minecraft.version
    }
        
    // copy everything else except the mcmod.info
    from(sourceSets.main.resources.srcDirs) {
        exclude 'mcmod.info'
    }
}